UEFN Verse: fort_character interface

The fort_character interface is used to define the capabilities of characters in Fortnite. It is associated with the character’s physical attributes and actions, such as health, shield, jumping, and crouching.

To better understand fort_character, let’s compare it with the agent class:

• agent: Represents the entity controlling the character, which can be a human player or an NPC. It has an identifier (id) that persists throughout the game session. It can be thought of as the brain.

• fort_character: Represents the agent within the game world. It can be thought of as the body of the agent. When a player is eliminated, the fort_character is destroyed, but the agent instance remains active. When entering a new match, a new fort_character is created and associated with the existing agent.

This interface inherits from and implements several other interfaces, including healthful, damageable, healable, shieldable, positional, game_action_instigator, and game_action_causer. It serves as the main interface for characters, since a fort_character instance provides access to the methods defined by all of these interfaces.

Tip: When looking through the documentation or the Fortnite.digest file for methods available in fort_character, you will only find the methods defined directly in that interface. However, all methods from the interfaces mentioned earlier are also accessible through fort_character. For example, the SetHealth() method belongs to the healthful interface and can be called from fort_character.

You can use the fort_character interface to modify health and shield, as well as determine whether the character is jumping, crouching, on the ground, in water, or in the air. There are many available features. 

To use the fort_character interface, the following module must be added:

using { /Fortnite.com/Characters }

This module adds an extension method to the agent class that returns the associated fort_character instance:

if( FortCharacter := Agent.GetFortCharacter[] ):

It is also possible to retrieve the agent associated with a fort_character, if one exists:

if ( Agent := FortCharacter.GetAgent[] ):

The example below demonstrates how to increase the health of a fort_character by 10:

CurrentHealth := FortCharacter.GetHealth()
FortCharacter.SetHealth( CurrentHealth + 10 )

As a practical example of using fort_character, we will create a device that references a volume_device. The device can restore the health and shield of agents located inside the referenced volume and provides several configuration options.

Open Verse Explorer, right-click on the project name, and select the option Add new Verse file to project.

In Device Name put recharger_device and click the Create Empty button.

Copy the Verse code below into the recharger_device file:

using { /Fortnite.com/Characters }
using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/Diagnostics }

recharger_device := class(creative_device):

    @editable
    VolumeDevice : volume_device = volume_device{}

    @editable
    TimeInterval : float = 1.0

    @editable
    HealthRegenAmount : float = 10.0;
    
    @editable
    ShieldRegenAmount : float = 10.0;

    @editable
    IsHealthRecharger : logic = true;

    @editable
    IsShieldRecharger : logic = true;

    var AgentsInVolume : []agent = array{}

    OnBegin<override>()<suspends>:void=

        loop: 
            Sleep(TimeInterval)

            set AgentsInVolume = VolumeDevice.GetAgentsInVolume()

            if(AgentsInVolume.Length > 0):

              for (Agent : AgentsInVolume):
                if(FortCharacter := Agent.GetFortCharacter[]):
                  if(IsHealthRecharger?):
                    CurrentHealth := FortCharacter.GetHealth()
                    FortCharacter.SetHealth(CurrentHealth + HealthRegenAmount)

                  if(IsShieldRecharger?):
                    CurrentShield := FortCharacter.GetShield()
                    FortCharacter.SetShield(CurrentShield + ShieldRegenAmount)

The device runs a loop every TimeInterval, which defaults to 1 second. On each iteration, it retrieves an array of agents inside the volume. For each agent, health and shield are increased if those options are enabled.

Save the file and compile the Verse code using the Verse > Compile Verse Code option from the UEFN menu.

Access the Content Drawer and add the recharger_device to the level. Then add a Volume Device and check the Visible in Game option.

Select the recharger_device in the level. In the Details panel, assign the reference to the Volume Device. You can also configure the device to restore only health or shield, as well as adjust the recharge amount and time interval.

To make testing easier, reduce the player's starting health. In the Outliner panel, select Island Settings. In the Details panel, search for Health and set Starting Health Percentage to 20%.

Save the level and click Launch Session to load it in Fortnite. Move the character into the volume to restore health and shield.

Table of Contents Verse